Lowest block hash

For fun, I checked which block hash was the lowest, as ordered in the same way that the proof-of-work check orders block hashes. Turns out, the currently leading block was one found by nptmining.com.

Results

The currently lowest block hash is:
028a44fbfed41dfbfcf7967cf33e89262dd8ad4ed1fc371b423b50e08e6a73a60300000000000000, found on October 11, 2026.

It holds a 3 in the last word that defines a block hash. So we haven’t yet found a block hash with 0 in the last word but that should only be a matter of time.

A zero in the last digest word would be required if the difficulty was 2^{64} \approx 18\cdot10^{18}, 18 quintillion, or 18 million trillion. At the time of writing, the difficulty is 200 trillion, so if difficulty rises by a factor 100,000, then all blocks hashes will have a zero in their last word. Once the cumulative proof-of-work value hits 9 quintillion, there is a 50 % chance that a block hash with zero in the last word will have been found. This value is currently 1.75 quintillion.

Method

Assuming you are running a neptune-core instance, all block hashes can be found with the command neptune-cli latest-tip-digests <n> where n can be set to a number higher than the current block height. For example, neptune-cli latest-tip-digests 1000000.

To find the lowest with one command, using GNU utils, you can run

{ neptune-cli tip-digest
  neptune-cli latest-tip-digests "$(neptune-cli block-height | awk '{print $NF}')"
} | awk '{
      key = ""
      for (k = 4; k >= 0; k--) {             # Ord compares word 4 first, then 3, ..., 0
        w = substr($0, 16 * k + 1, 16)       # word k: hex bytes 8k..8k+7
        for (b = 7; b >= 0; b--)             # little-endian -> big-endian
          key = key substr(w, 2 * b + 1, 2)
      }
      print key, $0
    }' | LC_ALL=C sort | head -n 1 | cut -d' ' -f2
1 Like

Extreme blocks on other parameters can be found with these parameters

# 1. One line per canonical block (genesis excluded), fields tab-separated. Takes minutes to run.
tip=$(neptune-cli block-height | awk '{print $NF}')
seq 1 "$tip" \
  | xargs -P 4 -n 1 sh -c 'sleep 0.0005; neptune-cli block-info "$1" | paste -sd "\t" -' _ \
  > block_info.tsv

# 2. The extremes.
awk -F'\t' '
# Thousand separators for the integer part of a decimal string.
function commify(s,    sign, whole, frac, out) {
  sign = ""; if (substr(s, 1, 1) == "-") { sign = "-"; s = substr(s, 2) }
  whole = s; frac = ""
  if (index(s, ".")) { whole = substr(s, 1, index(s, ".") - 1); frac = substr(s, index(s, ".")) }
  out = ""
  while (length(whole) > 3) { out = "," substr(whole, length(whole) - 2) out; whole = substr(whole, 1, length(whole) - 3) }
  return sign whole out frac
}
# Whether integer string a is larger than b, at any size.
function bigger(a, b) {
  return length(a) != length(b) ? length(a) > length(b) : a > b
}
{
  delete v
  for (i = 1; i <= NF; i++) { split($i, kv, ": "); v[kv[1]] = kv[2] }
  n = split("num_inputs num_announcements fee num_outputs size difficulty coinbase_amount", keys, " ")
  for (k = 1; k <= n; k++) {
    key = keys[k]; x = v[key]
    if (key == "difficulty")           better = !(key in best) || bigger(x, best[key])
    else if (key == "coinbase_amount") better = !(key in best) || x + 0 < best[key] + 0
    else                               better = !(key in best) || x + 0 > best[key] + 0
    if (better) { best[key] = x; at[key] = v["height"] " " v["digest"] }
  }
}
END {
  for (k = 1; k <= n; k++) {
    label = (keys[k] == "coinbase_amount" ? "lowest " : "highest ") keys[k]
    printf "%-26s %-30s height %s\n", label, commify(best[keys[k]]), at[keys[k]]
  }
}' block_info.tsv

Results

As of today

highest num_inputs         101                            height 5552 3564a79f473df66e1836d893e6f7d85977d2025e8c301c4c16d023b6c92a3b212d19a90100000000
highest num_announcements  71                             height 40595 68f936950bc6de63e6b55ad593616d470f7f709a257e19bc807b532ac4613af86f14370000000000
highest fee                328.00000000                   height 38002 161f17e53a3e9802ef50de5368936453c5b155443aebc396ed62f5a24a056ab8a2be1e0000000000
highest num_outputs        70                             height 11004 047b431a67b467103c1b2b2a2c9e7d0ed81fb1c35dcc87791dc6434b2c92d78be08d0b0000000000
highest size               338,493                        height 37919 0626540fbbed87713598ee686ac97b3381a7a89d35494c307351ffe56cbad611e4971a0000000000
highest difficulty         326,754,551,543,500            height 60547 da85497709b158ab8fc6e8bbaca70c840cbcecc6220da8b2a3afc53ce92882aea075000000000000
lowest coinbase_amount     128.00000000                   height 1 2a9b685b2f9cde0d6f258dcd3ab575ddabddd16d70f56e9b3ea7072e77a50aff95ad22c128000000
1 Like